To change the fonts for the title "Table of Contents," for the procedure name, and for the link beneath the procedure name, modify the appropriate style-element:

• The style element ContentTitle is responsible for rendering the title.
• The style element ContentProcname is responsible for rendering the procedure name. If the ODS PROCLABEL statement is used to specify a new label, then the style element ContentProclabel would be used rather then style element ContentProcname.
• The style element ContentItem is responsible for rendering the link beneath the procedure name, and the Style element BycontentFolder is responsible for the BY-values.

Below is an example. View output.

proc template;
   define style styles.test;
   parent=styles.default;
     style contents from contents
        "Controls the content title at the top " /
         font=(arial,1);
     style contentprocname from indexprocname
       "controls the procedure name " /
        font=(arial,1);
     style contentproclabel from contentproclabel
        "controls the label replacing the procedure name " /
        font=(arial,1);
     style contentfolder from contentfolder
        "controls the label beneath the procedure name" /
        font=(arial,1);
     style contentitem from indexitem
        "controls the item is the list" /
        font=(arial,1);
     style Bycontentfolder from Bycontentfolder
       "controls the by-variable info " /
     font=(arial,1);
   end;
run;

ods html body='temp.html'
contents='temp1.html'
frame='frame.html' style=styles.test;

proc tabulate data=sashelp.class;
class age;
var height;
table age,height;
run;

ods html close;

See also the full PROC TEMPLATE FAQ and Concepts.