You can use the CLUSTER option together with the HCCME= option in the MODEL statement to obtain heteroscedasticity- and cluster-adjusted standard errors in the PANEL procedure. The HCCME= option provides five different forms of a heteroscedasticity-consistent covariance matrix. Four of these, HCCME=0, 1, 2, or 3, can be specified together with the CLUSTER option to obtain a heteroscedasticity- and cluster-adjusted covariance matrix. HCCME=0 specifies White's original heteroscedasticity-consistent covariance matrix. HCCME=1, 2, and 3 specify three modified versions of the White heteroscedasticity-consistent covariance matrix. You can specify the HCCME= option without the CLUSTER option, but if the CLUSTER option is specified, then the HCCME= option must also be specified. For more details, including formulas, for these heteroscedasticity-consistent covariance matrices with and without cluster adjustment, see the PANEL procedure chapter in the SAS/ETS^® User's Guide.

The HCCME= and CLUSTER options can be applied to most of the models supported in the PANEL procedure, excepting only the dynamic panel model. Supported models include fixed effects models, random effects models, hybrid models, pooled OLS regression, between-group regression, the Parks method for autoregressive models, and the Da Silva method for moving average models. In the case of one-way and two-way fixed effects models, the variances for cross sectional and time dummy variables and the covariances with and between the dummy variables are not corrected. For two-way fixed effects models, the variances and covariances for the intercept are not corrected. That is because, in fixed effects models, the dummy variables are removed by the within transformations, and their variances and covariances cannot be calculated in the same way as for the other regressors. If you want the correction to apply to variances for the fixed effects dummy variables, and/or to the intercept for the two-way fixed effects models, you can specify the fixed effects in the CLASS and MODEL statements and specify the POOLED option instead of the FIXONE or FIXTWO option. Example 1 below illustrates the usage of the HCCME= and CLUSTER options in fixed effects models with the POOLED option compared to the FIXONE or FIXTWO options.

The cluster adjustment in PROC PANEL is on the cross sectional dimension only, which accounts for correlations within the cross sections. PROC PANEL does not currently provide two-way cluster adjustment. To instead apply the cluster adjustment to the time dimension, which accounts for correlations within the same time period, sort the data by the time period ID variable and then by the cross sectional ID variable. Also specify the time period ID variable before the cross sectional ID variable in the ID statement. Note that the PANEL procedure takes the first ID variable as the cross sectional ID and the second ID variable as time period ID. Example 2 below illustrates this approach.

When fitting a fixed effects model or a pooled OLS regression model, to adjust the standard errors on an arbitrary cluster variable that is neither the cross sectional ID variable nor the time period ID variable, use the following steps. First, sort your data according to the cluster variable. Then create a pseudo time period ID variable within the cluster variable using a DATA step. That transforms the data set into a panel data set with the cluster variable as the cross sectional ID variable and the pseudo time period ID variable as the time period ID variable. Next, in the PROC PANEL step, specify the cluster variable followed by the pseudo time period ID variable in the ID statement. Finally, specify the POOLED, HCCME=, and CLUSTER options in the MODEL statement and specify the fixed effects in the CLASS and MODEL statements.

Similarly, if the data is not panel data and you want to fit an OLS regression with fixed effects and obtain cluster-adjusted standard errors, you can still use the PANEL procedure. To do this, create a pseudo time period ID variable within the clusters using a DATA step, thus creating a pseudo panel data set to be read by the PANEL procedure. Then specify the cluster variable as the cross sectional ID variable, followed by the pseudo time period ID variable in the ID statement, and specify the fixed effects in the CLASS and MODEL statements. Also specify the POOLED, HCCME=, and CLUSTER options in the MODEL statement. Example 3 below illustrates how to create the pseudo time period ID variable according to the cluster variable and obtain cluster-adjusted standard errors when the data is not panel data. The same method also applies in the case of panel data when the cluster variable is neither the cross sectional ID nor the time period ID.

Below are some examples of using the HCCME= and CLUSTER options in the PANEL procedure. The data sets used in the examples are from published sources that have been well studied in the literature. The models fit to these data sets, and the heteroscedasticity and cluster adjustment options specified in the examples are for illustration purposes only. The following examples do not recommend specific models or specific covariance adjustments for these data sets. Consequently, no comment is made regarding the model fit statistics or the significance of the parameter estimates.

Example 1: Cluster adjustment of standard errors by cross section in fixed effects models with panel data

Consider a fixed effects model using the cost function data in Greene (1990). Production is the log of output in millions of kilowatt-hours, and Cost is the log of cost in millions of dollars. The one-way, fixed effects model is specified as follows.

C_it = β₀ + β₁P_it + v_i + e_it ,

where i=1, 2, ..., N and t=1, 2, ... , T. C_it is the cost for firm i at time t, P_it is the production for firm i at time t, v_i is the fixed effect for firm i, and the e_it are independent and identically distributed errors with zero mean and variance σ²_e.

The following steps create the Electricity data set and sort the data according to the cross section (Firm) and time period (Year).

    data Electricity;
        input Firm Year Production Cost @@;
        datalines;
     1 1955   5.36598   1.14867  1 1960   6.03787   1.45185
     1 1965   6.37673   1.52257  1 1970   6.93245   1.76627
     2 1955   6.54535   1.35041  2 1960   6.69827   1.71109
     2 1965   7.40245   2.09519  2 1970   7.82644   2.39480
     3 1955   8.07153   2.94628  3 1960   8.47679   3.25967
     3 1965   8.66923   3.47952  3 1970   9.13508   3.71795
     4 1955   8.64259   3.56187  4 1960   8.93748   3.93400
     4 1965   9.23073   4.11161  4 1970   9.52530   4.35523
     5 1955   8.69951   3.50116  5 1960   9.01457   3.68998
     5 1965   9.04594   3.76410  5 1970   9.21074   4.05573
     6 1955   9.37552   4.29114  6 1960   9.65188   4.59356
     6 1965  10.21163   4.93361  6 1970  10.34039   5.25520
     ;
     
     proc sort data=Electricity;
        by firm year;
        run; 

The following PROC PANEL step fits the one-way, fixed effects model with heteroscedasticity and cluster adjustment on the cross sections (Firms). The FIXONE option in the MODEL statement requests the one-way, fixed effects model. The HCCME=1 option requests the White heteroscedasticity-consistent covariance matrix modified by a degree of freedom adjustment. The CLUSTER option specifies cluster adjustment on the cross sections. The PRINTFIXED option displays the fixed effects estimates in the Parameter Estimates table.

  proc panel data=Electricity;
     id firm year;
     model cost = production / fixone printfixed hccme=1 cluster;
     run; 

Below are the parameter estimates along with their standard errors, t statistics, and p-values. Following this table, a note appears indicating that the standard errors for the fixed effects estimates are not corrected for heteroscedasticity or clustering.

Parameter Estimates Variable DF Estimate Standard Error t Value Pr > |t| Label CS1 1 -0.79001 0.2437 -3.24 0.0048 Cross Sectional Effect 1 CS2 1 -1.00821 0.1913 -5.27 <.0001 Cross Sectional Effect 2 CS3 1 -0.53644 0.1189 -4.51 0.0003 Cross Sectional Effect 3 CS4 1 -0.23097 0.1011 -2.28 0.0355 Cross Sectional Effect 4 CS5 1 -0.40732 0.1040 -3.92 0.0011 Cross Sectional Effect 5 Intercept 1 -1.90352 1.1705 -1.63 0.1223 Intercept Production 1 0.67428 0.1183 5.70 <.0001     Note: Fixed effects parameters are not HCCME corrected.

The following step also provides heteroscedasticity- and cluster-corrected standard errors for the fixed effects parameters. The POOLED option in the MODEL statement requests pooled OLS regression. The CLASS and MODEL statements include the cross sectional ID variable, Firm. The HCCME= and CLUSTER options request the degree of freedom adjustment to White's heteroscedasticity-consistent covariance matrix and cluster adjustment. This model is equivalent to the one-way, fixed effects model specified using the FIXONE option above, but the heteroscedasticity and cluster adjustment is applied to all parameters in the model including the fixed effects parameters.

  proc panel data=Electricity;
     id firm year;
     class firm;
     model cost = production firm / pooled hccme=1 cluster;
     run; 

The parameter estimates, their standard errors, t statistics, and associated p-values are shown below. Compared to the FIXONE model above, all parameter estimates remain the same. Also, the standard errors, t statistics, and p-values for the intercept and Production slope parameter remain the same. However, the standard errors, t statistics, and p-values of the Firm fixed effects are adjusted by the POOLED option for heteroscedasticity and clustering and therefore differ from the previous results using the FIXONE option.

Parameter Estimates Variable DF Estimate Standard Error t Value Pr > |t| Label Intercept 1 -1.90352 1.1705 -1.63 0.1223 Intercept Production 1 0.67428 0.1183 5.70 <.0001   FIRM1 1 -0.79001 0.4397 -1.80 0.0901 FIRM = 1 FIRM2 1 -1.00821 0.3285 -3.07 0.0069 FIRM = 2 FIRM3 1 -0.53644 0.1546 -3.47 0.0029 FIRM = 3 FIRM4 1 -0.23097 0.0959 -2.41 0.0277 FIRM = 4 FIRM5 1 -0.40732 0.1067 -3.82 0.0014 FIRM = 5 FIRM6 0 0 . . . FIRM = 6

For the two-way, fixed effects model, replace the FIXONE option with the FIXTWO option in the MODEL statement. The standard errors for the cross section and time period fixed effects and the intercept parameter are not heteroscedasticity- and cluster-adjusted. If you want to adjust the standard errors for these parameters as well, specify the fixed effects in the CLASS and MODEL statements and specify the POOLED, HCCME=, and CLUSTER options in the MODEL statement similar to the FIXONE case.

Example 2: Cluster adjustment of standard errors by time in fixed effects models with panel data

Using the same data set as in Example 1 above, suppose you want to fit a one-way, fixed effects model on time. The model is specified as follows,

C_it = β₀ + β₁P_it + u_t + e_it ,

where i=1, 2, ..., N, t=1, 2, ... , T, and u_t is the fixed effect of time (Year). Otherwise, the model is as in Example 1.

If you want to obtain cluster-adjusted standard errors on the time dimension, sort the data according to the time period first before sorting by cross sections, and specify the time ID variable, Year, before the cross sectional ID variable, Firm, in the ID statement. PROC PANEL takes the first ID variable as the cross sectional ID variable and cluster adjustment is always on the cross sectional dimension. Then specify the one-way, fixed effects model with the FIXONE option in the MODEL statement. Also specify the HCCME= and CLUSTER options in the MODEL statement to apply the cluster adjustment to Years rather than Firms. This syntax is illustrated in the following steps.

proc sort data=Electricity out=sort_time;
     by year firm;
     run;
     
  proc panel data=sort_time;
     id year firm;
     model cost = production / fixone printfixed hccme=1 cluster;
     run; 

The parameter estimates, standard errors, t statistics, and the associated p-values are shown below. Note that the estimates for the CS fixed effects dummy variables, CS1, CS2, and CS3, are actually time fixed effects dummy variables, since Year is specified before Firm in the ID statement. PROC PANEL proceeds as if Years are the cross sections, resulting in the cluster adjustment on time dimension. The note below the table indicates that the fixed effects parameters are not heteroscedasticity and cluster adjusted.

Parameter Estimates Variable DF Estimate Standard Error t Value Pr > |t| Label CS1 1 0.15141 0.1322 1.15 0.2664 Cross Sectional Effect 1 CS2 1 0.140094 0.1293 1.08 0.2922 Cross Sectional Effect 2 CS3 1 0.032561 0.1275 0.26 0.8012 Cross Sectional Effect 3 Intercept 1 -4.37044 0.3729 -11.72 <.0001 Intercept Production 1 0.901784 0.0422 21.35 <.0001     Note: Fixed effects parameters are not HCCME corrected.

To also obtain heteroscedasticity- and cluster-adjusted standard errors on the fixed effects parameters, specify the POOLED, HCCME=, and CLUSTER options in the MODEL statement and specify Year in the CLASS and MODEL statements as in Example 1.

  proc panel data=sort_time;
     id year firm;
     class year; 
     model cost = production year / pooled hccme=1 cluster;
     run;

The following table shows the parameter estimates, standard errors, t statistics, and p-values. Note that all the parameter estimates remain the same as in the FIXONE model. The standard errors for the intercept and Production slope parameter are also the same. However, the standard errors for the Year dummy variables are different from the FIXONE model because these are heteroscedasticity- and cluster-adjusted in the POOLED model while those in the FIXONE model are not.

Parameter Estimates Variable DF Estimate Standard Error t Value Pr > |t| Label Intercept 1 -4.37044 0.3729 -11.72 <.0001 Intercept Production 1 0.901784 0.0422 21.35 <.0001   YEAR1955 1 0.15141 0.0441 3.43 0.0028 YEAR = 1955 YEAR1960 1 0.140094 0.0292 4.79 0.0001 YEAR = 1960 YEAR1965 1 0.032561 0.0143 2.27 0.0347 YEAR = 1965 YEAR1970 0 0 . . . YEAR = 1970

Example 3: Cluster adjustment of standard errors in OLS regression with fixed effects using non-panel data or using panel data with a cluster variable that is neither the cross sectional ID nor the time ID

Because PROC PANEL is designed specifically for panel data, you need to have a panel data set and specify a cross sectional ID variable and a time period ID variable in the ID statement to perform any regression in the procedure. In order to use the PANEL procedure to obtain cluster-adjusted standard errors in OLS regression with fixed effects using non-panel data, you need to create a pseudo time ID variable within the clusters. Then specify the cluster variable as the cross sectional ID variable and the pseudo time ID variable as the time period ID variable in the ID statement. In addition, specify the POOLED, HCCME=, and CLUSTER options in the MODEL statement to request pooled OLS regression with heteroscedasticity- and cluster-adjusted standard errors. Follow the same steps if you have panel data but the cluster variable on which you want to obtain cluster adjustment is neither the cross sectional ID variable nor the time period ID variable.

In the following data from Milliken and Johnson (1984), six people (Person) operate each of three machines (Machine) either one, two, or three times, and an overall rating (Rating) of the machine is recorded each time the machine is operated. Consider both Machine and Person as fixed effects. The dependent variable is the overall rating. The independent variables are the fixed effects of Machine and Person. The following steps create the data set.

     data Machine;
        input Machine Person Rating @@;
        datalines;
     1 1 52.0  1 2 51.8  1 2 52.8  1 3 60.0  1 4 51.1  1 4 52.3  1 5 50.9
     1 5 51.8  1 5 51.4  1 6 46.4  1 6 44.8  1 6 49.2  2 1 64.0  2 2 59.7
     2 2 60.0  2 2 59.0  2 3 68.6  2 3 65.8  2 4 63.2  2 4 62.8  2 4 62.2
     2 5 64.8  2 5 65.0  2 6 43.7  2 6 44.2  2 6 43.0  3 1 67.5  3 1 67.2
     3 1 66.9  3 2 61.5  3 2 61.7  3 2 62.3  3 3 70.8  3 3 70.6  3 3 71.0
     3 4 64.1  3 4 66.2  3 4 64.0  3 5 72.1  3 5 72.0  3 5 71.1  3 6 62.0
     3 6 61.4  3 6 60.5
     ; 

To obtain standard errors adjusted for the Machine clusters, which accounts for correlations within machines, sort the data by Machine and specify Machine as the cross sectional ID variable.

After sorting, the following DATA step creates a pseudo time period index variable to be specified as the time period ID variable in the ID statement in PROC PANEL. With the BY statement, FIRST.MACHINE identifies the first observation within each Machine and the INDEX_VAR variable is initialized to zero for this observation. The INDEX_VAR+1 statement then creates the observation index within each Machine. The PROC PRINT step displays the first 20 observations of the resulting data set.

    proc sort data=Machine;
        by machine;
        run;
     
     data cluster_machine;
        set machine;
        by machine;
        if first.machine then index_var = 0;
        index_var + 1;
        run;
     
     proc print data=cluster_machine(obs=20);
        run; 

Obs Machine Person Rating index_var 1 1 1 52.0 1 2 1 2 51.8 2 3 1 2 52.8 3 4 1 3 60.0 4 5 1 4 51.1 5 6 1 4 52.3 6 7 1 5 50.9 7 8 1 5 51.8 8 9 1 5 51.4 9 10 1 6 46.4 10 11 1 6 44.8 11 12 1 6 49.2 12 13 2 1 64.0 1 14 2 2 59.7 2 15 2 2 60.0 3 16 2 2 59.0 4 17 2 3 68.6 5 18 2 3 65.8 6 19 2 4 63.2 7 20 2 4 62.8 8

The following PROC PANEL step fits the pooled OLS regression model with Machine and Person fixed effects and with standard errors adjusted for the Machine clusters on the intercept and both Machine and Person fixed effects estimates. The ID statement specifies Machine as the cross sectional ID variable and index_var as the time period ID variable. The CLASS and MODEL statements specify Machine and Person fixed effects. The POOLED option requests pooled OLS regression. The HCCME=1 option requests the degree of freedom adjustment modification to White's heteroscedasticity-consistent covariance matrix. The CLUSTER option specifies cluster adjustment on the covariance matrix.

     proc panel data=cluster_machine;
        id machine index_var;
        class machine person;
        model rating = machine person / pooled hccme=1 cluster; 
        run; 

The results are shown below.

Parameter Estimates Variable DF Estimate Standard Error t Value Pr > |t| Label Intercept 1 57.3781 3.4713 16.53 <.0001 Intercept MACHINE1 1 -13.9586 0.4144 -33.69 <.0001 MACHINE = 1 MACHINE2 1 -6.44237 0.1955 -32.95 <.0001 MACHINE = 2 MACHINE3 0 0 . . . MACHINE = 3 PERSON1 1 10.22209 4.1347 2.47 0.0183 PERSON = 1 PERSON2 1 7.127437 4.2798 1.67 0.1045 PERSON = 2 PERSON3 1 14.89579 4.0885 3.64 0.0008 PERSON = 3 PERSON4 1 9.264937 4.6327 2.00 0.0531 PERSON = 4 PERSON5 1 11.85447 4.3773 2.71 0.0103 PERSON = 5 PERSON6 0 0 . . . PERSON = 6

To adjust the standard errors for Person clusters instead of Machine clusters, accounting for correlations within Person rather than Machine, proceed similarly as above. First, sort the data by Person and use Person as the cross sectional ID variable. Then create a pseudo time period ID variable within each person using the BY statement in the DATA step.

     proc sort data=Machine out=cluster_person;
        by person;
        run;
     
     data cluster_person;
        set cluster_person;
        by person;
        if first.person then index_var = 0;
        index_var + 1;
        run;
     
     proc print data=cluster_person(obs=13);
        run; 

The first 13 observations are shown below.

Obs Machine Person Rating index_var 1 1 1 52.0 1 2 2 1 64.0 2 3 3 1 67.5 3 4 3 1 67.2 4 5 3 1 66.9 5 6 1 2 51.8 1 7 1 2 52.8 2 8 2 2 59.7 3 9 2 2 60.0 4 10 2 2 59.0 5 11 3 2 61.5 6 12 3 2 61.7 7 13 3 2 62.3 8

In PROC PANEL, specify Person as the cross sectional ID variable and index_var as the time period ID variable in the ID statement. The CLASS and MODEL statements specify Machine and Person as fixed effects. The POOLED option requests pooled OLS regression. The HCCME=1 and CLUSTER options request the heteroscedasticity-consistent covariance matrix adjusted for Person clusters.

     proc panel data=cluster_person;
        id person index_var;
        class machine person;
        model rating = machine person / pooled hccme=1 cluster; 
        run; 

The results are shown below.

Parameter Estimates Variable DF Estimate Standard Error t Value Pr > |t| Label Intercept 1 57.3781 1.2206 47.01 <.0001 Intercept MACHINE1 1 -13.9586 1.8712 -7.46 <.0001 MACHINE = 1 MACHINE2 1 -6.44237 2.8794 -2.24 0.0315 MACHINE = 2 MACHINE3 0 0 . . . MACHINE = 3 PERSON1 1 10.22209 0.4882 20.94 <.0001 PERSON = 1 PERSON2 1 7.127437 0.1819 39.17 <.0001 PERSON = 2 PERSON3 1 14.89579 0.3119 47.76 <.0001 PERSON = 3 PERSON4 1 9.264937 0.1819 50.92 <.0001 PERSON = 4 PERSON5 1 11.85447 0.2409 49.20 <.0001 PERSON = 5 PERSON6 0 0 . . . PERSON = 6

References

Greene, W. H. (1990). Econometric Analysis. New York: Macmillan.

Milliken, G. A., and Johnson, D. E. (1984). Designed Experiments. Vol. 1 of Analysis of Messy Data. Belmont, CA: Lifetime Learning Publications.