Designs without blocking or covariates

To evaluate an existing design, use the INITDESIGN= and METHOD=SEQUENTIAL options in the GENERATE statement in PROC OPTEX. Specify the name of the design to be evaluated in the INITDESIGN= option. Since the efficiencies depend on the set of candidate points from which the design was drawn, you also need to specify the candidate data set in the DATA= option of the PROC OPTEX statement. Also, use the CODING=ORTHCAN option in the PROC OPTEX statement so that the orthogonal coding uses only the candidate points and not the points in the INITDESIGN= data set.

Following is an example of constructing a design from a candidate set of all possible runs and then reproducing the efficiencies in a separate step that evaluates the already-constructed design relative to the candidate set.

/* Generate candidate points */
proc factex;
   factors  feedrate catalyst agitrate temperat concentn;
   output out=one  feedrate  nvals=(10  15 )
                   catalyst  nvals=(1   2  )
                   agitrate  nvals=(100 120)
                   temperat  nvals=(140 180)
                   concentn  nvals=(3   6  );
   run;

/* Generate the design */
proc optex seed=27513 data=one;
   class feedrate catalyst agitrate temperat concentn;
   model feedrate catalyst agitrate temperat concentn
                  catalyst*temperat temperat*concentn;
   generate n=8;
   output out=design number=10;
   run;

/* Evaluate an existing design */
proc optex data=one coding=orthcan;
   class feedrate catalyst agitrate temperat concentn;
   model feedrate catalyst agitrate temperat concentn
                  catalyst*temperat temperat*concentn;
   generate n=8 initdesign=design method=sequential;
   run;

Designs with covariates

For designs with covariates, specify the INIT=CHAIN and ITER=0 options in the BLOCKS statement in addition to the INITDESIGN= and METHOD=SEQUENTIAL options in the GENERATE statement and the CODING=ORTHCAN option in the PROC OPTEX statement. This is illustrated in the example titled "Optimal Design with Fixed Covariates" in the OPTEX documentation.

Blocked designs

For optimally blocked designs, use the ITER=0, INIT=CHAIN, and NOEXCHANGE options in the BLOCKS statement as well as the INITDESIGN= and METHOD=SEQUENTIAL options in the GENERATE statement. As before, specify the CODING=ORTHCAN option in the PROC OPTEX statement.

In the following statements, the first OPTEX step constructs a balanced incomplete block design (BIBD) and the second OPTEX step evaluates this design replicating the efficiencies given in the construction step.

data can;
   do tmt = 1 to 7;
      output;
      end;
   run;

proc optex data=can seed=73462 coding=orth;
   class tmt;
   model tmt;
   blocks structure=(7)3;
   output out=bibd;
   run;

proc optex data=can seed=73462 coding=orthcan;
   class tmt;
   model tmt;
   generate initdesign=bibd method=sequential;
   blocks structure=(7)3 iter=0 init=chain noexchange;
   output out=eval;
   run;