The ODS LAYOUT GRIDDED option ROW_SPAN might create incorrect or unexpected output in the ODS destination for PowerPoint. You might encounter two different incorrect behaviors.

• The first incorrect behavior occurs when one region is designated to span multiple rows. It might force another region within the same layout container to start on a new slide even though it should appear on the same slide as the first region.
• The second incorrect behavior occurs when the region does not span the specified rows. The output object is placed in only the first row.

There is currently no circumvention for these issues.

The code below contains two separate programs that demonstrates both problems. The first program demonstrates the problem in which ROW_SPAN incorrectly places output on a second slide. The second program demonstrates the problem in which ROW_SPAN is not being applied.

/* The PROC MEANS output is forced to a second slide.*/
ods powerpoint file="example1.ppt";

ods layout start columns=2 column_widths=(47pct 47pct);

   ods region row_span=2;
      ods text= "row_span=2";

   ods region;
      proc print data=sashelp.class(obs=10);
         var name age;
      run;

   ods region;
      ods noproctitle;
      proc means data=sashelp.class n mean;
      run;

ods layout end;

ods _all_ close;

 

/* The PROC REPORT output on the right is placed only on the first row. */
/* It is not spanning two rows as specified. */
ods powerpoint file="example2.pptx";

title;
footnote;
ods layout gridded
    width=24.0cm columns=3 column_widths=(8.8cm 8.8cm 5.4cm)
    rows=2 row_heights=(6.0cm  6.6cm) column_gutter=0.4cm row_gutter=1cm;

   ods region;
      proc report data=sashelp.class(obs=4) 
           style(report)={width=100pct}
           style(header)={fontsize=8pt background=cxadd8e6}
           style(column)={fontsize=8pt};
         column name ("Demographcis" sex age height weight);
      run;

   ods region;
      proc report data=sashelp.class(obs=4)
           style(report)={width=100pct}
           style(header)={fontsize=8pt background=cxadd8e6}
           style(column)={fontsize=8pt};
         column name ("Demographcis"  height weight);
      run;

 
   ods region row_span=2;
      proc report data=sashelp.class(obs=3) noheader
           style(report)={width=100pct};
         column name;
      run;

   ods region;
      ods graphics / width=8.7cm height=6.6cm;
      proc sgplot data=sashelp.class;
         vbar age;
      run;

   ods region;
      ods graphics / width=8.7cm height=6.6cm;
      proc sgplot data=sashelp.class;
         histogram age;
      run;

ods _all_ close;