When you use PROC POWER to compute the sample size for certain analyses, it is possible that the resulting rounded-up sample size and actual power have a very small range. When this happens, the resulting plot might show only one or two plotting symbols. A more meaningful plot can be obtained by specifying the NFRACTIONAL option in PROC POWER analysis statement.

In the following example, you want to compute the sample size for a test of the Pearson correlation between two variables. The following statements compute the sample size assuming two scenarios for the correlation size, 0.5 and 0.99, in a one-sided test with power ranging from 0.3 to 0.9. The PLOT statement displays the power curves for both correlation sizes. The ODS OUTPUT statement saves the plotted power and sample size data.

proc power;
   ods output plotcontent=p;
   onecorr test=pearson dist=t model=fixed sides=1 alpha=0.05 
           corr=0.5 0.99 power=0.3 to 0.9 by 0.1
           ntotal=.
           ;
   plot x=power;  
   run;

These statements display the actual (or achieved) power (Power), nominal (or original) power (NominalPower) and rounded-up sample size (NTotal) data for the Corr=0.99 power curve.

 proc print data=p;
    where Corr=0.99;
    by Corr;
    id Corr;
    var NTotal NominalPower Power;
    run;

After rounding up, all sample sizes are identical (3), resulting in the achieved (or actual) power values also being identical (0.943). Consequently, a single point is plotted for this scenario.

A single point is displayed for correlation size 0.99 because the achieved power at the rounded-up sample size solutions is plotted, not the nominal (or original) power. Adding the NFRACTIONAL option in the ONECORR analysis statement plots the nominal power and the fractional sample size resulting in a more meaningful plot.

 proc power;
    ods output plotcontent=p2;
    onecorr test=pearson dist=t model=fixed sides=1 alpha=0.05
            corr=0.5 0.99 power=0.3 to 0.9 by 0.1
            ntotal=. nfractional
            ;
    plot x=power;  
    run; 

These statements display the power and sample size data used in the plot that resulted from the NFRACTIONAL option. The nominal power values now appear in the Power variable and the fractional sample sizes appear in the NTotal variable.

 proc print data=p2;
    where Corr=0.99;
    by Corr;
    id Corr;
    var NTotal Power;
    run;

Notice that fractional sample sizes and nominal power values vary resulting in a power curve, rather than a single point, in the above plot.